mirror of
https://github.com/xmonad/xmonad-contrib.git
synced 2025-05-19 03:20:21 -07:00
3d65a6bf72
Essentially, whenever the tutorial actually has decent material on the
subject matter. The replacement is roughly done as follows:
- logHook → tutorial
- keybindings → tutorial, as this is thoroughly covered
- manageHook → tutorial + X.D.Extending, as the manageHook stuff the
tutorial talks about is a little bit of an afterthought.
- X.D.Extending (on its own) → tutorial + X.D.Extending
- layoutHook → tutorial + X.D.Extending, as the tutorial, while
talking about layouts, doesn't necessarily have a huge focus there.
- mouse bindings → leave this alone, as the tutorial does not at all
talk about them.
72 lines
2.4 KiB
Haskell
72 lines
2.4 KiB
Haskell
-----------------------------------------------------------------------------
|
|
-- |
|
|
-- Module : XMonad.Actions.FindEmptyWorkspace
|
|
-- Description : Find an empty workspace.
|
|
-- Copyright : (c) Miikka Koskinen 2007
|
|
-- License : BSD3-style (see LICENSE)
|
|
--
|
|
-- Maintainer : arcatan@kapsi.fi
|
|
-- Stability : stable
|
|
-- Portability : unportable
|
|
--
|
|
-- Find an empty workspace.
|
|
--
|
|
-----------------------------------------------------------------------------
|
|
|
|
module XMonad.Actions.FindEmptyWorkspace (
|
|
-- * Usage
|
|
-- $usage
|
|
viewEmptyWorkspace, tagToEmptyWorkspace, sendToEmptyWorkspace
|
|
) where
|
|
|
|
import XMonad.Prelude
|
|
import XMonad
|
|
import XMonad.StackSet
|
|
|
|
-- $usage
|
|
--
|
|
-- To use, import this module into your @~\/.xmonad\/xmonad.hs@:
|
|
--
|
|
-- > import XMonad.Actions.FindEmptyWorkspace
|
|
--
|
|
-- and add the desired keybindings, for example:
|
|
--
|
|
-- > , ((modm, xK_m ), viewEmptyWorkspace)
|
|
-- > , ((modm .|. shiftMask, xK_m ), tagToEmptyWorkspace)
|
|
--
|
|
-- Now you can jump to an empty workspace with @mod-m@. @Mod-shift-m@
|
|
-- will tag the current window to an empty workspace and view it.
|
|
--
|
|
-- For detailed instructions on editing your key bindings, see
|
|
-- <https://xmonad.org/TUTORIAL.html#customizing-xmonad the tutorial>.
|
|
|
|
-- | Find the first hidden empty workspace in a StackSet. Returns
|
|
-- Nothing if all workspaces are in use. Function searches currently
|
|
-- focused workspace, other visible workspaces (when in Xinerama) and
|
|
-- hidden workspaces in this order.
|
|
findEmptyWorkspace :: StackSet i l a s sd -> Maybe (Workspace i l a)
|
|
findEmptyWorkspace = find (isNothing . stack) . allWorkspaces
|
|
where
|
|
allWorkspaces ss = (workspace . current) ss :
|
|
(map workspace . visible) ss ++ hidden ss
|
|
|
|
withEmptyWorkspace :: (WorkspaceId -> X ()) -> X ()
|
|
withEmptyWorkspace f = do
|
|
ws <- gets windowset
|
|
whenJust (findEmptyWorkspace ws) (f . tag)
|
|
|
|
-- | Find and view an empty workspace. Do nothing if all workspaces are
|
|
-- in use.
|
|
viewEmptyWorkspace :: X ()
|
|
viewEmptyWorkspace = withEmptyWorkspace (windows . view)
|
|
|
|
-- | Tag current window to an empty workspace and view it. Do nothing if
|
|
-- all workspaces are in use.
|
|
tagToEmptyWorkspace :: X ()
|
|
tagToEmptyWorkspace = withEmptyWorkspace $ \w -> windows $ view w . shift w
|
|
|
|
-- | Send current window to an empty workspace. Do nothing if
|
|
-- all workspaces are in use.
|
|
sendToEmptyWorkspace :: X ()
|
|
sendToEmptyWorkspace = withEmptyWorkspace $ \w -> windows $ shift w
|