extra-source-files for the new manpage

This resolves http://code.google.com/p/xmonad/issues/detail?id=320 by adding a
--verbose-version option yielding output like "xmonad 0.9 compiled by ghc 6.10 for linux/i386"

Main.hs

@@ -16,14 +16,18 @@ module Main (main) where
 
 import XMonad
 
+import Control.Monad (unless)
 import System.IO
 import System.Info
 import System.Environment
 import System.Posix.Process (executeFile)
+import System.Exit (exitFailure)
 
 import Paths_xmonad (version)
 import Data.Version (showVersion)
 
+import Graphics.X11.Xinerama (compiledWithXinerama)
+
 #ifdef TESTING
 import qualified Properties
 #endif
@@ -37,14 +41,21 @@ main = do
     let launch = catchIO buildLaunch >> xmonad defaultConfig
     case args of
         []                    -> launch
-        ["--resume", _]       -> launch
+        ("--resume":_)        -> launch
         ["--help"]            -> usage
-        ["--recompile"]       -> recompile True >> return ()
-        ["--version"]         -> putStrLn ("xmonad " ++ showVersion version)
+        ["--recompile"]       -> recompile True >>= flip unless exitFailure
+        ["--restart"]         -> sendRestart >> return ()
+        ["--version"]         -> putStrLn $ unwords shortVersion
+        ["--verbose-version"] -> putStrLn . unwords $ shortVersion ++ longVersion
 #ifdef TESTING
         ("--run-tests":_)     -> Properties.main
 #endif
         _                     -> fail "unrecognized flags"
+ where
+    shortVersion = ["xmonad", showVersion version]
+    longVersion  = [ "compiled by", compilerName, showVersion compilerVersion
+                   , "for",  arch ++ "-" ++ os
+                   , "\nXinerama:", show compiledWithXinerama ]
 
 usage :: IO ()
 usage = do
@@ -55,6 +66,7 @@ usage = do
         "  --help                       Print this message" :
         "  --version                    Print the version number" :
         "  --recompile                  Recompile your ~/.xmonad/xmonad.hs" :
+        "  --restart                    Request a running xmonad process to restart" :
 #ifdef TESTING
         "  --run-tests                  Run the test suite" :
 #endif
@@ -66,7 +78,7 @@ usage = do
 --
 --   * ghc missing
 --
---   * "~\/.xmonad\/xmonad.hs" missing
+--   * both "~\/.xmonad\/xmonad.hs" and "~\/.xmonad\/xmonad-$arch-$os" missing
 --
 --   * xmonad.hs fails to compile
 --
@@ -83,3 +95,14 @@ buildLaunch = do
     args <- getArgs
     executeFile (dir ++ "/xmonad-"++arch++"-"++os) False args Nothing
     return ()
+
+sendRestart :: IO ()
+sendRestart = do
+    dpy <- openDisplay ""
+    rw <- rootWindow dpy $ defaultScreen dpy
+    xmonad_restart <- internAtom dpy "XMONAD_RESTART" False
+    allocaXEvent $ \e -> do
+        setEventType e clientMessage
+        setClientMessageEvent e rw xmonad_restart 32 0 currentTime
+        sendEvent dpy rw False structureNotifyMask e
+    sync dpy False

XMonad/Config.hs

@@ -25,20 +25,24 @@ module XMonad.Config (defaultConfig) where
 -- Useful imports
 --
 import XMonad.Core as XMonad hiding
-    (workspaces,manageHook,numlockMask,keys,logHook,startupHook,borderWidth,mouseBindings
-    ,layoutHook,modMask,terminal,normalBorderColor,focusedBorderColor,focusFollowsMouse)
+    (workspaces,manageHook,keys,logHook,startupHook,borderWidth,mouseBindings
+    ,layoutHook,modMask,terminal,normalBorderColor,focusedBorderColor,focusFollowsMouse
+    ,handleEventHook)
 import qualified XMonad.Core as XMonad
-    (workspaces,manageHook,numlockMask,keys,logHook,startupHook,borderWidth,mouseBindings
-    ,layoutHook,modMask,terminal,normalBorderColor,focusedBorderColor,focusFollowsMouse)
+    (workspaces,manageHook,keys,logHook,startupHook,borderWidth,mouseBindings
+    ,layoutHook,modMask,terminal,normalBorderColor,focusedBorderColor,focusFollowsMouse
+    ,handleEventHook)
 
 import XMonad.Layout
 import XMonad.Operations
 import XMonad.ManageHook
 import qualified XMonad.StackSet as W
 import Data.Bits ((.|.))
+import Data.Monoid
 import qualified Data.Map as M
 import System.Exit
 import Graphics.X11.Xlib
+import Graphics.X11.Xlib.Extras
 
 -- | The default number of workspaces (virtual screens) and their names.
 -- By default we use numeric strings, but any string may be used as a
@@ -60,22 +64,6 @@ workspaces = map show [1 .. 9 :: Int]
 defaultModMask :: KeyMask
 defaultModMask = mod1Mask
 
--- | The mask for the numlock key. Numlock status is "masked" from the
--- current modifier status, so the keybindings will work with numlock on or
--- off. You may need to change this on some systems.
---
--- You can find the numlock modifier by running "xmodmap" and looking for a
--- modifier with Num_Lock bound to it:
---
--- > $ xmodmap | grep Num
--- > mod2        Num_Lock (0x4d)
---
--- Set numlockMask = 0 if you don't have a numlock key, or want to treat
--- numlock status separately.
---
-numlockMask :: KeyMask
-numlockMask = mod2Mask
-
 -- | Width of the window border in pixels.
 --
 borderWidth :: Dimension
@@ -119,6 +107,15 @@ manageHook = composeAll
 logHook :: X ()
 logHook = return ()
 
+------------------------------------------------------------------------
+-- Event handling
+
+-- | Defines a custom handler function for X Events. The function should
+-- return (All True) if the default handler is to be run afterwards.
+-- To combine event hooks, use mappend or mconcat from Data.Monoid.
+handleEventHook :: Event -> X All
+handleEventHook _ = return (All True)
+
 -- | Perform an arbitrary action at xmonad startup.
 startupHook :: X ()
 startupHook = return ()
@@ -205,7 +202,7 @@ keys conf@(XConfig {XMonad.modMask = modMask}) = M.fromList $
 
     -- quit, or restart
     , ((modMask .|. shiftMask, xK_q     ), io (exitWith ExitSuccess)) -- %! Quit xmonad
-    , ((modMask              , xK_q     ), restart "xmonad" True) -- %! Restart xmonad
+    , ((modMask              , xK_q     ), spawn "xmonad --recompile && xmonad --restart") -- %! Restart xmonad
     ]
     ++
     -- mod-[1..9] %! Switch to workspace N
@@ -243,11 +240,12 @@ defaultConfig = XConfig
     , XMonad.terminal           = terminal
     , XMonad.normalBorderColor  = normalBorderColor
     , XMonad.focusedBorderColor = focusedBorderColor
-    , XMonad.numlockMask        = numlockMask
     , XMonad.modMask            = defaultModMask
     , XMonad.keys               = keys
     , XMonad.logHook            = logHook
     , XMonad.startupHook        = startupHook
     , XMonad.mouseBindings      = mouseBindings
     , XMonad.manageHook         = manageHook
-    , XMonad.focusFollowsMouse  = focusFollowsMouse }
+    , XMonad.handleEventHook    = handleEventHook
+    , XMonad.focusFollowsMouse  = focusFollowsMouse
+    }

XMonad/Core.hs

@@ -24,7 +24,8 @@ module XMonad.Core (
     XConf(..), XConfig(..), LayoutClass(..),
     Layout(..), readsLayout, Typeable, Message,
     SomeMessage(..), fromMessage, LayoutMessages(..),
-    runX, catchX, userCode, userCodeDef, io, catchIO, installSignalHandlers,
+    StateExtension(..), ExtensionClass(..),
+    runX, catchX, userCode, userCodeDef, io, catchIO, installSignalHandlers, uninstallSignalHandlers,
     withDisplay, withWindowSet, isRoot, runOnWorkspaces,
     getAtom, spawn, spawnPID, getXMonadDir, recompile, trace, whenJust, whenX,
     atom_WM_STATE, atom_WM_PROTOCOLS, atom_WM_DELETE_WINDOW, ManageHook, Query(..), runQuery
@@ -33,14 +34,16 @@ module XMonad.Core (
 import XMonad.StackSet hiding (modify)
 
 import Prelude hiding ( catch )
-import Control.Exception (catch, try, bracket, throw, Exception(ExitException))
+import Control.Exception (catch, try, bracket, throw, finally, Exception(ExitException))
 import Control.Applicative
 import Control.Monad.State
 import Control.Monad.Reader
+import System.FilePath
 import System.IO
 import System.Info
-import System.Posix.Process (executeFile, forkProcess, getAnyProcessStatus)
+import System.Posix.Process (executeFile, forkProcess, getAnyProcessStatus, createSession)
 import System.Posix.Signals
+import System.Posix.IO
 import System.Posix.Types (ProcessID)
 import System.Process
 import System.Directory
@@ -48,19 +51,26 @@ import System.Exit
 import Graphics.X11.Xlib
 import Graphics.X11.Xlib.Extras (Event)
 import Data.Typeable
-import Data.Maybe (isJust)
+import Data.List ((\\))
+import Data.Maybe (isJust,fromMaybe)
 import Data.Monoid
-import Data.Maybe (fromMaybe)
 
 import qualified Data.Map as M
 import qualified Data.Set as S
 
 -- | XState, the (mutable) window manager state.
 data XState = XState
-    { windowset    :: !WindowSet           -- ^ workspace list
-    , mapped       :: !(S.Set Window)      -- ^ the Set of mapped windows
-    , waitingUnmap :: !(M.Map Window Int)  -- ^ the number of expected UnmapEvents
-    , dragging     :: !(Maybe (Position -> Position -> X (), X ())) }
+    { windowset        :: !WindowSet                     -- ^ workspace list
+    , mapped           :: !(S.Set Window)                -- ^ the Set of mapped windows
+    , waitingUnmap     :: !(M.Map Window Int)            -- ^ the number of expected UnmapEvents
+    , dragging         :: !(Maybe (Position -> Position -> X (), X ()))
+    , numlockMask  :: !KeyMask                           -- ^ The numlock modifier
+    , extensibleState  :: !(M.Map String (Either String StateExtension))
+    -- ^ stores custom state information.
+    --
+    -- The module XMonad.Utils.ExtensibleState in xmonad-contrib
+    -- provides additional information and a simple interface for using this.
+    }
 
 -- | XConf, the (read-only) window manager configuration.
 data XConf = XConf
@@ -86,8 +96,10 @@ data XConfig l = XConfig
     , terminal           :: !String              -- ^ The preferred terminal application. Default: \"xterm\"
     , layoutHook         :: !(l Window)          -- ^ The available layouts
     , manageHook         :: !ManageHook          -- ^ The action to run when a new window is opened
+    , handleEventHook    :: !(Event -> X All)    -- ^ Handle an X event, returns (All True) if the default handler
+                                                 -- should also be run afterwards. mappend should be used for combining
+                                                 -- event hooks in most cases.
     , workspaces         :: ![String]            -- ^ The list of workspaces' names
-    , numlockMask        :: !KeyMask             -- ^ The numlock modifier
     , modMask            :: !KeyMask             -- ^ the mod modifier
     , keys               :: !(XConfig Layout -> M.Map (ButtonMask,KeySym) (X ()))
                                                  -- ^ The key binding: a map from key presses and actions
@@ -124,7 +136,7 @@ data ScreenDetail   = SD { screenRect :: !Rectangle } deriving (Eq,Show, Read)
 --
 newtype X a = X (ReaderT XConf (StateT XState IO) a)
 #ifndef __HADDOCK__
-    deriving (Functor, Monad, MonadIO, MonadState XState, MonadReader XConf)
+    deriving (Functor, Monad, MonadIO, MonadState XState, MonadReader XConf, Typeable)
 #endif
 
 instance Applicative X where
@@ -337,6 +349,33 @@ data LayoutMessages = Hide              -- ^ sent when a layout becomes non-visi
 
 instance Message LayoutMessages
 
+-- ---------------------------------------------------------------------
+-- Extensible state
+--
+
+-- | Every module must make the data it wants to store
+-- an instance of this class.
+--
+-- Minimal complete definition: initialValue
+class Typeable a => ExtensionClass a where
+    -- | Defines an initial value for the state extension
+    initialValue :: a
+    -- | Specifies whether the state extension should be
+    -- persistent. Setting this method to 'PersistentExtension'
+    -- will make the stored data survive restarts, but
+    -- requires a to be an instance of Read and Show.
+    --
+    -- It defaults to 'StateExtension', i.e. no persistence.
+    extensionType :: a -> StateExtension
+    extensionType = StateExtension
+
+-- | Existential type to store a state extension.
+data StateExtension =
+    forall a. ExtensionClass a => StateExtension a
+    -- ^ Non-persistent state extension
+  | forall a. (Read a, Show a, ExtensionClass a) => PersistentExtension a
+    -- ^ Persistent extension
+
 -- ---------------------------------------------------------------------
 -- | General utilities
 --
@@ -354,8 +393,17 @@ catchIO f = io (f `catch` \e -> hPrint stderr e >> hFlush stderr)
 spawn :: MonadIO m => String -> m ()
 spawn x = spawnPID x >> return ()
 
+-- | Like 'spawn', but returns the 'ProcessID' of the launched application
 spawnPID :: MonadIO m => String -> m ProcessID
-spawnPID x = io $ forkProcess $ executeFile "/bin/sh" False ["-c", x] Nothing
+spawnPID x = io . forkProcess . finally nullStdin $ do
+                uninstallSignalHandlers
+                createSession
+                executeFile "/bin/sh" False ["-c", x] Nothing
+ where
+    nullStdin = do
+        fd <- openFd "/dev/null" ReadOnly Nothing defaultFileFlags
+        dupTo fd stdInput
+        closeFd fd
 
 -- | This is basically a map function, running a function in the 'X' monad on
 -- each workspace with the output of that function being the modified workspace.
@@ -392,18 +440,20 @@ recompile :: MonadIO m => Bool -> m Bool
 recompile force = io $ do
     dir <- getXMonadDir
     let binn = "xmonad-"++arch++"-"++os
-        bin  = dir ++ "/" ++ binn
-        base = dir ++ "/" ++ "xmonad"
+        bin  = dir </> binn
+        base = dir </> "xmonad"
         err  = base ++ ".errors"
         src  = base ++ ".hs"
+        lib  = dir </> "lib"
+    libTs <- mapM getModTime . Prelude.filter isSource =<< allFiles lib
     srcT <- getModTime src
     binT <- getModTime bin
-    if (force || srcT > binT)
+    if force || any (binT <) (srcT : libTs)
       then do
         -- temporarily disable SIGCHLD ignoring:
-        installHandler sigCHLD Default Nothing
+        uninstallSignalHandlers
         status <- bracket (openFile err WriteMode) hClose $ \h -> do
-            waitForProcess =<< runProcess "ghc" ["--make", "xmonad.hs", "-i", "-no-recomp", "-v0", "-o",binn] (Just dir)
+            waitForProcess =<< runProcess "ghc" ["--make", "xmonad.hs", "-i", "-ilib", "-fforce-recomp", "-v0", "-o",binn] (Just dir)
                                     Nothing Nothing Nothing (Just h)
 
         -- re-enable SIGCHLD:
@@ -423,6 +473,12 @@ recompile force = io $ do
         return (status == ExitSuccess)
       else return True
  where getModTime f = catch (Just <$> getModificationTime f) (const $ return Nothing)
+       isSource = flip elem [".hs",".lhs",".hsc"]
+       allFiles t = do
+            let prep = map (t</>) . Prelude.filter (`notElem` [".",".."])
+            cs <- prep <$> catch (getDirectoryContents t) (\_ -> return [])
+            ds <- filterM doesDirectoryExist cs
+            concat . ((cs \\ ds):) <$> mapM allFiles ds
 
 -- | Conditionally run an action, using a @Maybe a@ to decide.
 whenJust :: Monad m => Maybe a -> (a -> m ()) -> m ()
@@ -447,3 +503,9 @@ installSignalHandlers = io $ do
         x <- getAnyProcessStatus False False
         when (isJust x) more
     return ()
+
+uninstallSignalHandlers :: MonadIO m => m ()
+uninstallSignalHandlers = io $ do
+    installHandler openEndedPipe Default Nothing
+    installHandler sigCHLD Default Nothing
+    return ()

XMonad/Layout.hs

@@ -51,9 +51,9 @@ instance LayoutClass Full a
 
 -- | The builtin tiling mode of xmonad. Supports 'Shrink', 'Expand' and
 -- 'IncMasterN'.
-data Tall a = Tall !Int      -- ^ The default number of windows in the master pane (default: 1)
-                   !Rational -- ^ Default proportion of screen occupied by master pane (default: 1/2)
-                   !Rational -- ^ Percent of screen to increment by when resizing panes (default: 3/100)
+data Tall a = Tall { tallNMaster :: !Int               -- ^ The default number of windows in the master pane (default: 1)
+                   , tallRatioIncrement :: !Rational   -- ^ Percent of screen to increment by when resizing panes (default: 3/100)
+                   , tallRatio :: !Rational }          -- ^ Default proportion of screen occupied by master pane (default: 1/2)
                 deriving (Show, Read)
                         -- TODO should be capped [0..1] ..
 

XMonad/Main.hsc

@@ -15,6 +15,7 @@
 
 module XMonad.Main (xmonad) where
 
+import Control.Arrow (second)
 import Data.Bits
 import Data.List ((\\))
 import qualified Data.Map as M
@@ -22,6 +23,7 @@ import qualified Data.Set as S
 import Control.Monad.Reader
 import Control.Monad.State
 import Data.Maybe (fromMaybe)
+import Data.Monoid (getAll)
 
 import Foreign.C
 import Foreign.Ptr
@@ -92,7 +94,6 @@ xmonad initxmc = do
     let layout = layoutHook xmc
         lreads = readsLayout layout
         initialWinset = new layout (workspaces xmc) $ map SD xinesc
-
         maybeRead reads' s = case reads' s of
                                 [(x, "")] -> Just x
                                 _         -> Nothing
@@ -102,6 +103,10 @@ xmonad initxmc = do
                     ws                   <- maybeRead reads s
                     return . W.ensureTags layout (workspaces xmc)
                            $ W.mapLayout (fromMaybe layout . maybeRead lreads) ws
+        extState = fromMaybe M.empty $ do
+                     ("--resume" : _ : dyns : _) <- return args
+                     vals                        <- maybeRead reads dyns
+                     return . M.fromList . map (second Left) $ vals
 
         cf = XConf
             { display       = dpy
@@ -113,15 +118,19 @@ xmonad initxmc = do
             , buttonActions = mouseBindings xmc xmc
             , mouseFocused  = False
             , mousePosition = Nothing }
-        st = XState
-            { windowset     = initialWinset
-            , mapped        = S.empty
-            , waitingUnmap  = M.empty
-            , dragging      = Nothing }
 
+        st = XState
+            { windowset       = initialWinset
+            , numlockMask   = 0
+            , mapped          = S.empty
+            , waitingUnmap    = M.empty
+            , dragging        = Nothing
+            , extensibleState = extState
+            }
     allocaXEvent $ \e ->
         runX cf st $ do
 
+            setNumlockMask
             grabKeys
             grabButtons
 
@@ -152,11 +161,18 @@ xmonad initxmc = do
         prehandle e = let mouse = do guard (ev_event_type e `elem` evs)
                                      return (fromIntegral (ev_x_root e)
                                             ,fromIntegral (ev_y_root e))
-                      in local (\c -> c { mousePosition = mouse }) (handle e)
+                      in local (\c -> c { mousePosition = mouse }) (handleWithHook e)
         evs = [ keyPress, keyRelease, enterNotify, leaveNotify
               , buttonPress, buttonRelease]
 
 
+-- | Runs handleEventHook from the configuration and runs the default handler
+-- function if it returned True.
+handleWithHook :: Event -> X ()
+handleWithHook e = do
+  evHook <- asks (handleEventHook . config)
+  whenX (userCodeDef True $ getAll `fmap` evHook e) (handle e)
+
 -- ---------------------------------------------------------------------
 -- | Event handler. Map X events onto calls into Operations.hs, which
 -- modify our internal model of the window manager state.
@@ -204,7 +220,9 @@ handle (UnmapEvent {ev_window = w, ev_send_event = synthetic}) = whenX (isClient
 -- set keyboard mapping
 handle e@(MappingNotifyEvent {}) = do
     io $ refreshKeyboardMapping e
-    when (ev_request e == mappingKeyboard) grabKeys
+    when (ev_request e `elem` [mappingKeyboard, mappingModifier]) $ do
+        setNumlockMask
+        grabKeys
 
 -- handle button release, which may finish dragging.
 handle e@(ButtonEvent {ev_event_type = t})
@@ -280,6 +298,12 @@ handle (ConfigureEvent {ev_window = w}) = whenX (isRoot w) rescreen
 handle PropertyEvent { ev_event_type = t, ev_atom = a }
     | t == propertyNotify && a == wM_NAME = userCodeDef () =<< asks (logHook . config)
 
+handle e@ClientMessageEvent { ev_message_type = mt } = do
+    a <- getAtom "XMONAD_RESTART"
+    if (mt == a)
+        then restart "xmonad" True
+        else broadcastMessage e
+
 handle e = broadcastMessage e -- trace (eventName e) -- ignoring
 
 
@@ -304,6 +328,18 @@ scan dpy rootw = do
                   return $ not (wa_override_redirect wa)
                          && (wa_map_state wa == waIsViewable || ic)
 
+setNumlockMask :: X ()
+setNumlockMask = do
+    dpy <- asks display
+    ms <- io $ getModifierMapping dpy
+    xs <- sequence [ do
+                        ks <- io $ keycodeToKeysym dpy kc 0
+                        if ks == xK_Num_Lock
+                            then return (setBit 0 (fromIntegral m))
+                            else return (0 :: KeyMask)
+                        | (m, kcs) <- ms, kc <- kcs, kc /= 0]
+    modify (\s -> s { numlockMask = foldr (.|.) 0 xs })
+
 -- | Grab the keys back
 grabKeys :: X ()
 grabKeys = do
@@ -315,7 +351,7 @@ grabKeys = do
          kc <- io $ keysymToKeycode dpy sym
          -- "If the specified KeySym is not defined for any KeyCode,
          -- XKeysymToKeycode() returns zero."
-         when (kc /= '\0') $ mapM_ (grab kc . (mask .|.)) =<< extraModifiers
+         when (kc /= 0) $ mapM_ (grab kc . (mask .|.)) =<< extraModifiers
 
 -- | XXX comment me
 grabButtons :: X ()

XMonad/ManageHook.hs

@@ -37,14 +37,16 @@ liftX = Query . lift
 idHook :: ManageHook
 idHook = doF id
 
--- | Compose two 'ManageHook's.
-(<+>) :: ManageHook -> ManageHook -> ManageHook
+-- | Infix 'mappend'. Compose two 'ManageHook' from right to left.
+(<+>) :: Monoid m => m -> m -> m
 (<+>) = mappend
 
 -- | Compose the list of 'ManageHook's.
 composeAll :: [ManageHook] -> ManageHook
 composeAll = mconcat
 
+infix 0 -->
+
 -- | @p --> x@.  If @p@ returns 'True', execute the 'ManageHook'.
 (-->) :: Query Bool -> ManageHook -> ManageHook
 p --> f = p >>= \b -> if b then f else mempty
@@ -71,7 +73,8 @@ title = ask >>= \w -> liftX $ do
         getProp =
             (internAtom d "_NET_WM_NAME" False >>= getTextProperty d w)
                 `catch` \_ -> getTextProperty d w wM_NAME
-        extract = fmap head . wcTextPropertyToTextList d
+        extract prop = do l <- wcTextPropertyToTextList d prop
+                          return $ if null l then "" else head l
     io $ bracket getProp (xFree . tp_value) extract `catch` \_ -> return ""
 
 -- | Return the application name.
@@ -111,4 +114,4 @@ doIgnore = ask >>= \w -> liftX (reveal w) >> doF (W.delete w)
 
 -- | Move the window to a given workspace
 doShift :: WorkspaceId -> ManageHook
-doShift = doF . W.shift
+doShift i = doF . W.shiftWin i =<< ask

XMonad/Operations.hs

@@ -68,7 +68,7 @@ manage w = whenX (not <$> isClient w) $ withDisplay $ \d -> do
             where i = W.tag $ W.workspace $ W.current ws
 
     mh <- asks (manageHook . config)
-    g <- fmap appEndo $ userCodeDef (Endo id) (runQuery mh w)
+    g <- appEndo <$> userCodeDef (Endo id) (runQuery mh w)
     windows (g . f)
 
 -- | unmanage. A window no longer exists, remove it from the window
@@ -155,13 +155,13 @@ windows f = do
 
     whenJust (W.peek ws) $ \w -> io $ setWindowBorder d w fbc
 
+    mapM_ reveal visible
+    setTopFocus
+
     -- hide every window that was potentially visible before, but is not
     -- given a position by a layout now.
     mapM_ hide (nub (oldvisible ++ newwindows) \\ visible)
 
-    mapM_ reveal visible
-    setTopFocus
-
     -- all windows that are no longer in the windowset are marked as
     -- withdrawn, it is important to do this after the above, otherwise 'hide'
     -- will overwrite withdrawnState with iconicState
@@ -389,13 +389,13 @@ isClient w = withWindowSet $ return . W.member w
 -- (numlock and capslock)
 extraModifiers :: X [KeyMask]
 extraModifiers = do
-    nlm <- asks (numlockMask . config)
+    nlm <- gets numlockMask
     return [0, nlm, lockMask, nlm .|. lockMask ]
 
 -- | Strip numlock\/capslock from a mask
 cleanMask :: KeyMask -> X KeyMask
 cleanMask km = do
-    nlm <- asks (numlockMask . config)
+    nlm <- gets numlockMask
     return (complement (nlm .|. lockMask) .&. km)
 
 -- | Get the 'Pixel' value for a named color
@@ -413,9 +413,13 @@ restart :: String -> Bool -> X ()
 restart prog resume = do
     broadcastMessage ReleaseResources
     io . flush =<< asks display
-    args <- if resume then gets (("--resume":) . return . showWs . windowset) else return []
+    let wsData = show . W.mapLayout show . windowset
+        maybeShow (t, Right (PersistentExtension ext)) = Just (t, show ext)
+        maybeShow (t, Left str) = Just (t, str)
+        maybeShow _ = Nothing
+        extState = return . show . catMaybes . map maybeShow . M.toList . extensibleState
+    args <- if resume then gets (\s -> "--resume":wsData s:extState s) else return []
     catchIO (executeFile prog True args Nothing)
- where showWs = show . W.mapLayout show
 
 ------------------------------------------------------------------------
 -- | Floating layer support

XMonad/StackSet.hs

@@ -52,7 +52,7 @@ module XMonad.StackSet (
     ) where
 
 import Prelude hiding (filter)
-import Data.Maybe   (listToMaybe,fromJust,isJust)
+import Data.Maybe   (listToMaybe,isJust)
 import qualified Data.List as L (deleteBy,find,splitAt,filter,nub)
 import Data.List ( (\\) )
 import qualified Data.Map  as M (Map,insert,delete,empty)
@@ -194,7 +194,8 @@ abort x = error $ "xmonad: StackSet: " ++ x
 -- Xinerama: Virtual workspaces are assigned to physical screens, starting at 0.
 --
 new :: (Integral s) => l -> [i] -> [sd] -> StackSet i l a s sd
-new l wids m | not (null wids) && length m <= length wids = StackSet cur visi unseen M.empty
+new l wids m | not (null wids) && length m <= length wids && not (null m)
+  = StackSet cur visi unseen M.empty
   where (seen,unseen) = L.splitAt (length m) $ map (\i -> Workspace i l Nothing) wids
         (cur:visi)    = [ Screen i s sd |  (i, s, sd) <- zip3 seen [0..] m ]
                 -- now zip up visibles with their screen id
@@ -538,10 +539,7 @@ focusMaster = modify' $ \c -> case c of
 -- element on the current stack, the original stackSet is returned.
 --
 shift :: (Ord a, Eq s, Eq i) => i -> StackSet i l a s sd -> StackSet i l a s sd
-shift n s | n `tagMember` s && n /= curtag = maybe s go (peek s)
-          | otherwise                      = s
-    where go w = view curtag . insertUp w . view n . delete' w $ s
-          curtag = currentTag s
+shift n s = maybe s (\w -> shiftWin n w s) (peek s)
 
 -- | /O(n)/. shiftWin. Searches for the specified window 'w' on all workspaces
 -- of the stackSet and moves it to stack 'n', leaving it as the focused
@@ -549,13 +547,12 @@ shift n s | n `tagMember` s && n /= curtag = maybe s go (peek s)
 -- focused element on that workspace.
 -- The actual focused workspace doesn't change. If the window is not
 -- found in the stackSet, the original stackSet is returned.
--- TODO how does this duplicate 'shift's behaviour?
 shiftWin :: (Ord a, Eq a, Eq s, Eq i) => i -> a -> StackSet i l a s sd -> StackSet i l a s sd
-shiftWin n w s | from == Nothing                     = s -- not found
-               | n `tagMember` s && (Just n) /= from = go
-               | otherwise                           = s
-    where from   = findTag w s
-
-          go     = on n (insertUp w) . on (fromJust from) (delete' w) $ s
-          on i f = view (currentTag s) . f . view i
+shiftWin n w s = case findTag w s of
+                    Just from | n `tagMember` s && n /= from -> go from s
+                    _                                        -> s
+ where go from = onWorkspace n (insertUp w) . onWorkspace from (delete' w)
 
+onWorkspace :: (Eq i, Eq s) => i -> (StackSet i l a s sd -> StackSet i l a s sd)
+            -> (StackSet i l a s sd -> StackSet i l a s sd)
+onWorkspace n f s = view (currentTag s) . f . view n $ s

man/xmonad.1.in

@@ -1,42 +0,0 @@
-./" man page created by David Lazar on April 24, 2007
-./" uses ``tmac.an'' macro set
-.TH xmonad 1 "18 April 07" xmonad\-1.0 "xmonad manual"
-.SH NAME
-xmonad \- a tiling window manager
-.SH DESCRIPTION
-.PP
-\fBxmonad\fR is a minimalist tiling window manager for X, written in Haskell. Windows are managed using automatic layout algorithms, which can be dynamically reconfigured. At any time windows are arranged so as to maximise the use of screen real estate. All features of the window manager are accessible purely from the keyboard: a mouse is entirely optional. \fBxmonad\fR is configured in Haskell, and custom layout algorithms may be implemented by the user in config files. A principle of \fBxmonad\fR is predictability: the user should know in advance precisely the window arrangement that will result from any action.
-.PP
-By default, \fBxmonad\fR provides three layout algorithms: tall, wide and fullscreen. In tall or wide mode, windows are tiled and arranged to prevent overlap and maximise screen use. Sets of windows are grouped together on virtual screens, and each screen retains its own layout, which may be reconfigured dynamically. Multiple physical monitors are supported via Xinerama, allowing simultaneous display of a number of screens.
-.PP
-By utilising the expressivity of a modern functional language with a rich static type system, \fBxmonad\fR provides a complete, featureful window manager in less than 1200 lines of code, with an emphasis on correctness and robustness. Internal properties of the window manager are checked using a combination of static guarantees provided by the type system, and type-based automated testing. A benefit of this is that the code is simple to understand, and easy to modify.
-.SH USAGE
-.PP
-\fBxmonad\fR places each window into a "workspace". Each workspace can have any number of windows, which you can cycle though with mod-j and mod-k. Windows are either displayed full screen, tiled horizontally, or tiled vertically. You can toggle the layout mode with mod-space, which will cycle through the available modes.
-.PP
-You can switch to workspace N with mod-N. For example, to switch to workspace 5, you would press mod-5. Similarly, you can move the current window to another workspace with mod-shift-N.
-.PP
-When running with multiple monitors (Xinerama), each screen has exactly 1 workspace visible. mod-{w,e,r} switch the focus between screens, while shift-mod-{w,e,r} move the current window to that screen. When \fBxmonad\fR starts, workspace 1 is on screen 1, workspace 2 is on screen 2, etc. When switching workspaces to one that is already visible, the current and visible workspaces are swapped.
-.PP
-.SS Flags
-\fBxmonad\fR has several flags which you may pass to the executable. These flags are:
-.TP
-\fB--recompile
-Recompiles your configuration in ~/.xmonad/xmonad.hs
-.TP
-\fB--version
-Display version of \fBxmonad\fR.
-.SS Default keyboard bindings
-___KEYBINDINGS___
-.SH EXAMPLES
-To use \fBxmonad\fR as your window manager add:
-.RS
-xmonad
-.RE
-to your \fI~/.xinitrc\fR file
-.SH CUSTOMIZATION
-\fBxmonad\fR is customized in ~/.xmonad/xmonad.hs, and then restarting with mod-q.
-.PP
-You can find many extensions to the core feature set in the xmonad-contrib package, available through your package manager or from http://xmonad.org/.
-.SH BUGS
-Probably. If you find any, please report them: http://code.google.com/p/xmonad/issues/list

man/xmonad.1.markdown

@@ -0,0 +1,99 @@
+#Name
+xmonad - a tiling window manager
+
+#Description
+
+_xmonad_ is a minimalist tiling window manager for X, written in Haskell.
+Windows are managed using automatic layout algorithms, which can be
+dynamically reconfigured. At any time windows are arranged so as to
+maximize the use of screen real estate. All features of the window manager
+are accessible purely from the keyboard: a mouse is entirely optional.
+_xmonad_ is configured in Haskell, and custom layout algorithms may be
+implemented by the user in config files. A principle of _xmonad_ is
+predictability: the user should know in advance precisely the window
+arrangement that will result from any action.
+
+By default, _xmonad_ provides three layout algorithms: tall, wide and
+fullscreen. In tall or wide mode, windows are tiled and arranged to prevent
+overlap and maximize screen use. Sets of windows are grouped together on
+virtual screens, and each screen retains its own layout, which may be
+reconfigured dynamically. Multiple physical monitors are supported via
+Xinerama, allowing simultaneous display of a number of screens.
+
+By utilizing the expressivity of a modern functional language with a rich
+static type system, _xmonad_ provides a complete, featureful window manager
+in less than 1200 lines of code, with an emphasis on correctness and
+robustness. Internal properties of the window manager are checked using a
+combination of static guarantees provided by the type system, and
+type-based automated testing. A benefit of this is that the code is simple
+to understand, and easy to modify.
+
+#Usage
+
+_xmonad_ places each window into a "workspace". Each workspace can have
+any number of windows, which you can cycle though with mod-j and mod-k.
+Windows are either displayed full screen, tiled horizontally, or tiled
+vertically. You can toggle the layout mode with mod-space, which will cycle
+through the available modes.
+
+You can switch to workspace N with mod-N. For example, to switch to
+workspace 5, you would press mod-5. Similarly, you can move the current
+window to another workspace with mod-shift-N.
+
+When running with multiple monitors (Xinerama), each screen has exactly 1
+workspace visible. mod-{w,e,r} switch the focus between screens, while
+shift-mod-{w,e,r} move the current window to that screen. When _xmonad_
+starts, workspace 1 is on screen 1, workspace 2 is on screen 2, etc. When
+switching workspaces to one that is already visible, the current and
+visible workspaces are swapped.
+
+##Flags
+xmonad  has  several flags which  you may pass to the executable.
+These flags are:
+
+--recompile
+:   Recompiles your configuration in _~/.xmonad/xmonad.hs_
+
+--restart
+:   Causes the currently running _xmonad_ process to restart
+
+--version
+:   Display version of _xmonad_
+
+--verbose-version
+:   Display detailed version of _xmonad_
+
+##Default keyboard bindings
+
+___KEYBINDINGS___
+
+#Examples
+To use xmonad as your window manager add to your _~/.xinitrc_ file:
+
+> exec xmonad
+
+#Customization
+xmonad is customized in ~/.xmonad/xmonad.hs,  and  then  restarting
+with mod-q.
+
+You can find many extensions to the core feature set in the xmonad-
+contrib package, available through your  package  manager  or  from
+[xmonad.org].
+
+##Modular Configuration
+As of _xmonad-0.9_, any additional Haskell modules may be placed in
+_~/.xmonad/lib/_ are available in GHC's searchpath. Hierarchical modules
+are supported: for example, the file
+_~/.xmonad/lib/XMonad/Stack/MyAdditions.hs_ could contain:
+
+> module XMonad.Stack.MyAdditions (function1) where
+>     function1 = error "function1: Not implemented yet!"
+
+Your xmonad.hs may then import XMonad.Stack.MyAdditions as if that
+module was contained within xmonad or xmonad-contrib.
+
+#Bugs
+Probably. If you find any, please report them to the [bugtracker]
+
+[xmonad.org]: http://xmonad.org
+[bugtracker]: http://code.google.com/p/xmonad/issues/list

man/xmonad.hs

@@ -8,6 +8,7 @@
 --
 
 import XMonad
+import Data.Monoid
 import System.Exit
 
 import qualified XMonad.StackSet as W
@@ -18,6 +19,10 @@ import qualified Data.Map        as M
 --
 myTerminal      = "xterm"
 
+-- Whether focus follows the mouse pointer.
+myFocusFollowsMouse :: Bool
+myFocusFollowsMouse = True
+
 -- Width of the window border in pixels.
 --
 myBorderWidth   = 1
@@ -29,21 +34,6 @@ myBorderWidth   = 1
 --
 myModMask       = mod1Mask
 
--- The mask for the numlock key. Numlock status is "masked" from the
--- current modifier status, so the keybindings will work with numlock on or
--- off. You may need to change this on some systems.
---
--- You can find the numlock modifier by running "xmodmap" and looking for a
--- modifier with Num_Lock bound to it:
---
--- > $ xmodmap | grep Num
--- > mod2        Num_Lock (0x4d)
---
--- Set numlockMask = 0 if you don't have a numlock key, or want to treat
--- numlock status separately.
---
-myNumlockMask   = mod2Mask
-
 -- The default number of workspaces (virtual screens) and their names.
 -- By default we use numeric strings, but any string may be used as a
 -- workspace name. The number of workspaces is determined by the length
@@ -63,73 +53,76 @@ myFocusedBorderColor = "#ff0000"
 ------------------------------------------------------------------------
 -- Key bindings. Add, modify or remove key bindings here.
 --
-myKeys conf@(XConfig {XMonad.modMask = modMask}) = M.fromList $
+myKeys conf@(XConfig {XMonad.modMask = modm}) = M.fromList $
 
     -- launch a terminal
-    [ ((modMask .|. shiftMask, xK_Return), spawn $ XMonad.terminal conf)
+    [ ((modm .|. shiftMask, xK_Return), spawn $ XMonad.terminal conf)
 
     -- launch dmenu
-    , ((modMask,               xK_p     ), spawn "exe=`dmenu_path | dmenu` && eval \"exec $exe\"")
+    , ((modm,               xK_p     ), spawn "exe=`dmenu_path | dmenu` && eval \"exec $exe\"")
 
     -- launch gmrun
-    , ((modMask .|. shiftMask, xK_p     ), spawn "gmrun")
+    , ((modm .|. shiftMask, xK_p     ), spawn "gmrun")
 
     -- close focused window
-    , ((modMask .|. shiftMask, xK_c     ), kill)
+    , ((modm .|. shiftMask, xK_c     ), kill)
 
      -- Rotate through the available layout algorithms
-    , ((modMask,               xK_space ), sendMessage NextLayout)
+    , ((modm,               xK_space ), sendMessage NextLayout)
 
     --  Reset the layouts on the current workspace to default
-    , ((modMask .|. shiftMask, xK_space ), setLayout $ XMonad.layoutHook conf)
+    , ((modm .|. shiftMask, xK_space ), setLayout $ XMonad.layoutHook conf)
 
     -- Resize viewed windows to the correct size
-    , ((modMask,               xK_n     ), refresh)
+    , ((modm,               xK_n     ), refresh)
 
     -- Move focus to the next window
-    , ((modMask,               xK_Tab   ), windows W.focusDown)
+    , ((modm,               xK_Tab   ), windows W.focusDown)
 
     -- Move focus to the next window
-    , ((modMask,               xK_j     ), windows W.focusDown)
+    , ((modm,               xK_j     ), windows W.focusDown)
 
     -- Move focus to the previous window
-    , ((modMask,               xK_k     ), windows W.focusUp  )
+    , ((modm,               xK_k     ), windows W.focusUp  )
 
     -- Move focus to the master window
-    , ((modMask,               xK_m     ), windows W.focusMaster  )
+    , ((modm,               xK_m     ), windows W.focusMaster  )
 
     -- Swap the focused window and the master window
-    , ((modMask,               xK_Return), windows W.swapMaster)
+    , ((modm,               xK_Return), windows W.swapMaster)
 
     -- Swap the focused window with the next window
-    , ((modMask .|. shiftMask, xK_j     ), windows W.swapDown  )
+    , ((modm .|. shiftMask, xK_j     ), windows W.swapDown  )
 
     -- Swap the focused window with the previous window
-    , ((modMask .|. shiftMask, xK_k     ), windows W.swapUp    )
+    , ((modm .|. shiftMask, xK_k     ), windows W.swapUp    )
 
     -- Shrink the master area
-    , ((modMask,               xK_h     ), sendMessage Shrink)
+    , ((modm,               xK_h     ), sendMessage Shrink)
 
     -- Expand the master area
-    , ((modMask,               xK_l     ), sendMessage Expand)
+    , ((modm,               xK_l     ), sendMessage Expand)
 
     -- Push window back into tiling
-    , ((modMask,               xK_t     ), withFocused $ windows . W.sink)
+    , ((modm,               xK_t     ), withFocused $ windows . W.sink)
 
     -- Increment the number of windows in the master area
-    , ((modMask              , xK_comma ), sendMessage (IncMasterN 1))
+    , ((modm              , xK_comma ), sendMessage (IncMasterN 1))
 
     -- Deincrement the number of windows in the master area
-    , ((modMask              , xK_period), sendMessage (IncMasterN (-1)))
+    , ((modm              , xK_period), sendMessage (IncMasterN (-1)))
 
-    -- toggle the status bar gap
-    -- TODO, update this binding with avoidStruts , ((modMask              , xK_b     ),
+    -- Toggle the status bar gap
+    -- Use this binding with avoidStruts from Hooks.ManageDocks.
+    -- See also the statusBar function from Hooks.DynamicLog.
+    --
+    -- , ((modm              , xK_b     ), sendMessage ToggleStruts)
 
     -- Quit xmonad
-    , ((modMask .|. shiftMask, xK_q     ), io (exitWith ExitSuccess))
+    , ((modm .|. shiftMask, xK_q     ), io (exitWith ExitSuccess))
 
     -- Restart xmonad
-    , ((modMask              , xK_q     ), restart "xmonad" True)
+    , ((modm              , xK_q     ), spawn "xmonad --recompile; xmonad --restart")
     ]
     ++
 
@@ -137,7 +130,7 @@ myKeys conf@(XConfig {XMonad.modMask = modMask}) = M.fromList $
     -- mod-[1..9], Switch to workspace N
     -- mod-shift-[1..9], Move client to workspace N
     --
-    [((m .|. modMask, k), windows $ f i)
+    [((m .|. modm, k), windows $ f i)
         | (i, k) <- zip (XMonad.workspaces conf) [xK_1 .. xK_9]
         , (f, m) <- [(W.greedyView, 0), (W.shift, shiftMask)]]
     ++
@@ -146,7 +139,7 @@ myKeys conf@(XConfig {XMonad.modMask = modMask}) = M.fromList $
     -- mod-{w,e,r}, Switch to physical/Xinerama screens 1, 2, or 3
     -- mod-shift-{w,e,r}, Move client to screen 1, 2, or 3
     --
-    [((m .|. modMask, key), screenWorkspace sc >>= flip whenJust (windows . f))
+    [((m .|. modm, key), screenWorkspace sc >>= flip whenJust (windows . f))
         | (key, sc) <- zip [xK_w, xK_e, xK_r] [0..]
         , (f, m) <- [(W.view, 0), (W.shift, shiftMask)]]
 
@@ -154,18 +147,18 @@ myKeys conf@(XConfig {XMonad.modMask = modMask}) = M.fromList $
 ------------------------------------------------------------------------
 -- Mouse bindings: default actions bound to mouse events
 --
-myMouseBindings (XConfig {XMonad.modMask = modMask}) = M.fromList $
+myMouseBindings (XConfig {XMonad.modMask = modm}) = M.fromList $
 
     -- mod-button1, Set the window to floating mode and move by dragging
-    [ ((modMask, button1), (\w -> focus w >> mouseMoveWindow w
-                                          >> windows W.shiftMaster))
+    [ ((modm, button1), (\w -> focus w >> mouseMoveWindow w
+                                       >> windows W.shiftMaster))
 
     -- mod-button2, Raise the window to the top of the stack
-    , ((modMask, button2), (\w -> focus w >> windows W.shiftMaster))
+    , ((modm, button2), (\w -> focus w >> windows W.shiftMaster))
 
     -- mod-button3, Set the window to floating mode and resize by dragging
-    , ((modMask, button3), (\w -> focus w >> mouseResizeWindow w
-                                          >> windows W.shiftMaster))
+    , ((modm, button3), (\w -> focus w >> mouseResizeWindow w
+                                       >> windows W.shiftMaster))
 
     -- you may also bind events to the mouse scroll wheel (button4 and button5)
     ]
@@ -216,20 +209,22 @@ myManageHook = composeAll
     , resource  =? "desktop_window" --> doIgnore
     , resource  =? "kdesktop"       --> doIgnore ]
 
--- Whether focus follows the mouse pointer.
-myFocusFollowsMouse :: Bool
-myFocusFollowsMouse = True
+------------------------------------------------------------------------
+-- Event handling
 
+-- * EwmhDesktops users should change this to ewmhDesktopsEventHook
+--
+-- Defines a custom handler function for X Events. The function should
+-- return (All True) if the default handler is to be run afterwards. To
+-- combine event hooks use mappend or mconcat from Data.Monoid.
+--
+myEventHook = mempty
 
 ------------------------------------------------------------------------
 -- Status bars and logging
 
 -- Perform an arbitrary action on each internal state change or X event.
--- See the 'DynamicLog' extension for examples.
---
--- To emulate dwm's status bar
---
--- > logHook = dynamicLogDzen
+-- See the 'XMonad.Hooks.DynamicLog' extension for examples.
 --
 myLogHook = return ()
 
@@ -262,7 +257,6 @@ defaults = defaultConfig {
         focusFollowsMouse  = myFocusFollowsMouse,
         borderWidth        = myBorderWidth,
         modMask            = myModMask,
-        numlockMask        = myNumlockMask,
         workspaces         = myWorkspaces,
         normalBorderColor  = myNormalBorderColor,
         focusedBorderColor = myFocusedBorderColor,
@@ -274,6 +268,7 @@ defaults = defaultConfig {
       -- hooks, layouts
         layoutHook         = myLayout,
         manageHook         = myManageHook,
+        handleEventHook    = myEventHook,
         logHook            = myLogHook,
         startupHook        = myStartupHook
     }

util/GenerateManpage.hs

@@ -1,7 +1,14 @@
+-- Unlike the rest of xmonad, this file is copyright under the terms of the
+-- GPL.
+
 --
 -- Generates man/xmonad.1 from man/xmonad.1.in by filling the list of
 -- keybindings with values scraped from Config.hs
 --
+-- Uses cabal to grab the xmonad version from xmonad.cabal
+--
+-- Uses pandoc to convert the "xmonad.1.markdown" to "xmonad.1"
+--
 -- Format for the docstrings in Config.hs takes the following form:
 --
 -- -- mod-x %! Frob the whatsit
@@ -14,12 +21,23 @@
 -- [ ((modMask .|. shiftMask, xK_Return), spawn "xterm") -- %! Launch an xterm
 --
 -- Here, mod-shift-return will be used as the keybinding name.
---
 import Control.Monad
+import Control.Applicative
 import Text.Regex.Posix
 import Data.Char
 import Data.List
 
+import Distribution.PackageDescription.Parse
+import Distribution.Verbosity
+import Distribution.Package
+import Distribution.PackageDescription
+import Text.PrettyPrint.HughesPJ
+import Distribution.Text
+
+import Text.Pandoc
+
+releaseDate = "25 October 09"
+
 trim :: String -> String
 trim = reverse . dropWhile isSpace . reverse . dropWhile isSpace
 
@@ -35,13 +53,42 @@ allBindings :: String -> [(String, String)]
 allBindings xs = map (binding . map trim) (xs =~ "(.*)--(.*)%!(.*)")
 
 -- FIXME: What escaping should we be doing on these strings?
-troff :: (String, String) -> String
-troff (key, desc) = ".IP\n \\fB" ++ key ++ "\\fR\n" ++ desc ++ "\n"
+markdownDefn :: (String, String) -> String
+markdownDefn (key, desc) = key ++ "\n:     " ++ desc
 
 replace :: Eq a => a -> a -> [a] -> [a]
 replace x y = map (\a -> if a == x then y else a)
 
+-- rawSystem "pandoc" ["--read=markdown","--write=man","man/xmonad.1.markdown"]
+
 main = do
-    troffBindings <- (concatMap troff . allBindings) `liftM` readFile "./XMonad/Config.hs"
-    let sed = unlines . replace "___KEYBINDINGS___" troffBindings . lines
-    readFile "./man/xmonad.1.in" >>= return . sed >>= writeFile "./man/xmonad.1"
+    releaseName <- (show . disp . package . packageDescription)
+                    `liftM`readPackageDescription normal "xmonad.cabal"
+    keybindings <- (intercalate "\n\n" . map markdownDefn . allBindings)
+                    `liftM` readFile "./XMonad/Config.hs"
+
+    let manHeader = unwords [".TH xmonad 1","\""++releaseDate++"\"",releaseName,"\"xmonad manual\""]
+        writeOpts = defaultWriterOptions -- { writerLiterateHaskell = True }
+
+    parsed <- readMarkdown defaultParserState { stateLiterateHaskell = True }
+        . unlines
+        . replace "___KEYBINDINGS___" keybindings
+        . lines
+        <$> readFile "./man/xmonad.1.markdown"
+
+    writeFile "./man/xmonad.1"
+        . (manHeader ++)
+        . writeMan writeOpts
+        $ parsed
+    putStrLn "Documentation created: man/xmonad.1"
+
+    writeFile "./man/xmonad.1.html"
+        . writeHtmlString writeOpts
+            { writerHeader = "<h1>"++releaseName++"</h1>"++
+                             "<p>Section: xmonad manual (1)<br>"++
+                             "Updated: "++releaseDate++"</p>"++
+                             "<hr>"
+            , writerStandalone = True
+            , writerTableOfContents = True }
+        $ parsed
+    putStrLn "Documentation created: man/xmonad.1.html"

xmonad.cabal

@@ -1,5 +1,5 @@
 name:               xmonad
-version:            0.8.1
+version:            0.9.1
 homepage:           http://xmonad.org
 synopsis:           A tiling window manager
 description:
@@ -18,11 +18,13 @@ license-file:       LICENSE
 author:             Spencer Janssen
 maintainer:         xmonad@haskell.org
 extra-source-files: README TODO CONFIG STYLE tests/loc.hs tests/Properties.hs
-                    man/xmonad.1.in man/xmonad.1 man/xmonad.html man/xmonad.hs
+                    man/xmonad.1.markdown man/xmonad.1 man/xmonad.1.html
                     util/GenerateManpage.hs
 cabal-version:      >= 1.2
 build-type:         Simple
 
+data-files:         man/xmonad.hs
+
 flag small_base
     description: Choose the new smaller, split-up base package.
 
@@ -41,10 +43,10 @@ library
                         XMonad.StackSet
 
     if flag(small_base)
-        build-depends: base < 4 && >=3, containers, directory, process
+        build-depends: base < 4 && >=3, containers, directory, process, filepath
     else
         build-depends: base < 3
-    build-depends: X11>=1.4.3, mtl, unix
+    build-depends: X11>=1.5.0.0 && < 1.6, mtl, unix
 
     ghc-options:        -funbox-strict-fields -Wall
     ghc-prof-options:   -prof -auto-all